blob: 0d2cbdbba2f75f4bb4210ab8e4cac3841b97eb83 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
@echo off
rem SPDX-License-Identifier: MIT
rem Copyright (C) 2019-2021 WireGuard LLC. All Rights Reserved.
setlocal
set BUILDDIR=%~dp0
set PATH=%BUILDDIR%..\.deps\llvm-mingw\bin;%BUILDDIR%..\.deps\go\bin;%PATH%
set PATHEXT=.exe
cd /d %BUILDDIR% || exit /b 1
if exist ..\.deps\prepared goto :build
:installdeps
call ..\build.bat || goto :error
:build
set GOOS=windows
set GOARM=7
set GOPATH=%BUILDDIR%..\.deps\gopath
set GOROOT=%BUILDDIR%..\.deps\go
set CGO_ENABLED=1
set CGO_CFLAGS=-O3 -Wall -Wno-unused-function -Wno-switch -std=gnu11 -DWINVER=0x0601
call :build_plat x86 i686 386 || goto :error
call :build_plat amd64 x86_64 amd64 || goto :error
rem Uncomment when cgo is implemented:
rem call :build_plat arm armv7 arm || goto :error
rem call :build_plat arm64 aarch64 arm64 || goto :error
:success
echo [+] Success
exit /b 0
:build_plat
set CC=%~2-w64-mingw32-gcc
set GOARCH=%~3
mkdir %1 >NUL 2>&1
echo [+] Building library %1
go build -buildmode c-shared -ldflags="-w -s" -trimpath -v -o "%~1/tunnel.dll" || exit /b 1
del "%~1\tunnel.h"
goto :eof
:error
echo [-] Failed with error #%errorlevel%.
cmd /c exit %errorlevel%
|