<machine/macros.h> would provide inline version of a few of the functions

traditionnaly found in libkern. However, the memcmp() flavour would behave
as bcmp() with only two possible return values: zero and positive non-zero.

This broke the name cache RB trees which now rely upon proper memcmp()
semantics(negative value, zero, or positive value).

Just give up on these macros and provide the same code as libc, in libkern.
As a side effect, this no longer uses the cmpc3 instruction, which is not
implemented and requires (slow) kernel emulation, on the original uVax.

10 files changed, 461 insertions, 152 deletions

diff --git a/sys/arch/vax/include/macros.h b/sys/arch/vax/include/macros.h
index 87bd942c43a..b39d64c9228 100644
--- a/sys/arch/vax/include/macros.h
+++ b/sys/arch/vax/include/macros.h
@@ -1,4 +1,4 @@
-/*	$OpenBSD: macros.h,v 1.15 2007/10/10 15:53:53 art Exp $ */
+/*	$OpenBSD: macros.h,v 1.16 2009/08/19 19:47:51 miod Exp $ */
 /*	$NetBSD: macros.h,v 1.20 2000/07/19 01:02:52 matt Exp $	*/
 
 /*
@@ -52,91 +52,6 @@ ffs(int reg)
 	return	val;
 }
 
-static __inline__ void *
-memcpy(void *toe, const void *from, size_t len)
-{
-	__asm__ __volatile ("movc3 %0,(%1),(%2)"
-			:
-			: "r" (len),"r" (from),"r"(toe)
-			:"r0","r1","r2","r3","r4","r5","memory","cc");
-	return toe;
-}
-static __inline__ void *
-memmove(void *toe, const void *from, size_t len)
-{
-	__asm__ __volatile ("movc3 %0,(%1),(%2)"
-			:
-			: "r" (len),"r" (from),"r"(toe)
-			:"r0","r1","r2","r3","r4","r5","memory","cc");
-	return toe;
-}
-
-#ifdef notnow
-static __inline__ void
-bcopy(const void *from, void *toe, size_t len)
-{
-	__asm__ __volatile ("movc3 %0,(%1),(%2)"
-			:
-			: "r" (len),"r" (from),"r"(toe)
-			:"r0","r1","r2","r3","r4","r5","memory","cc");
-}
-#endif
-
-void	blkfill(void *, int, size_t);
-
-static __inline__ void *
-memset(void *block, int c, size_t len)
-{
-	if (len > 65535)
-		blkfill(block, c, len);
-	else {
-		__asm__ __volatile ("movc5 $0,(%0),%2,%1,(%0)"
-			:
-			: "r" (block), "r" (len), "r"(c)
-			:"r0","r1","r2","r3","r4","r5","memory","cc");
-	}
-	return block;
-}
-
-static __inline__ void
-bzero(void *block, size_t len)
-{
-	if (len > 65535)
-		blkfill(block, 0, len);
-	else {
-		__asm__ __volatile ("movc5 $0,(%0),$0,%1,(%0)"
-			:
-			: "r" (block), "r" (len)
-			:"r0","r1","r2","r3","r4","r5","memory","cc");
-	}
-}
-
-/* XXX - the return syntax of memcmp is wrong */
-static __inline__ int
-memcmp(const void *b1, const void *b2, size_t len)
-{
-	register int ret;
-
-	__asm__ __volatile("cmpc3 %3,(%1),(%2);movl r0,%0"
-			: "=r" (ret)
-			: "r" (b1), "r" (b2), "r" (len)
-			: "r0","r1","r2","r3" );
-	return ret;
-}
-
-static __inline__ int
-bcmp(const void *b1, const void *b2, size_t len)
-{
-	register int ret;
-
-	__asm__ __volatile("cmpc3 %3,(%1),(%2);movl r0,%0"
-			: "=r" (ret)
-			: "r" (b1), "r" (b2), "r" (len)
-			: "r0","r1","r2","r3" );
-	return ret;
-}
-
-/* Begin nya */
 static __inline__ size_t
 strlen(const char *cp)
 {
diff --git a/sys/arch/vax/vax/subr.s b/sys/arch/vax/vax/subr.s
index 9b51e3017e6..c4db61b0e83 100644
--- a/sys/arch/vax/vax/subr.s
+++ b/sys/arch/vax/vax/subr.s
@@ -1,4 +1,4 @@
-/*	$OpenBSD: subr.s,v 1.29 2009/06/20 21:02:15 miod Exp $     */
+/*	$OpenBSD: subr.s,v 1.30 2009/08/19 19:47:53 miod Exp $     */
 /*	$NetBSD: subr.s,v 1.32 1999/03/25 00:41:48 mrg Exp $	   */
 
 /*
@@ -171,50 +171,6 @@ ENTRY(badaddr,R2|R3)			# Called with addr,b/w/l
 		movl	r3,r0
 		ret
 
-# Have bcopy and bzero here to be sure that system files that not gets
-# macros.h included will not complain.
-ENTRY(bcopy,R2|R3|R4|R5|R6)
-	movl	4(ap), r0
-	movl	8(ap), r1
-	movzwl	12(ap), r2
-	movzwl	14(ap), r6
-
-	movc3	r2, (r0), (r1)
-	
-	tstl	r6
-	bleq	1f
-0:	movb	(r1)+, (r3)+
-	movc3	$0xffff, (r1), (r3)
-	sobgtr	r6, 0b
-	
-1:	ret	
-
-ENTRY(bzero,R2|R3|R4|R5|R6)
-	movl	4(ap), r0
-	movzwl	8(ap), r1
-	movzwl	10(ap), r6
-	
-	movc5	$0, (r0), $0, r1, (r0)
-	
-	tstl	r6
-	bleq	1f
-0:	clrb	(r3)+
-	movc5	$0, (r3), $0, $0xffff, (r3)
-	sobgtr	r6, 0b
-	
-1:	ret
-
-# cmpc3 is sometimes emulated; we cannot use it
-ENTRY(bcmp, R2);
-    movl    4(ap), r2
-    movl    8(ap), r1
-    movl    12(ap), r0
-2:  cmpb    (r2)+, (r1)+
-    bneq    1f
-    decl    r0
-    bneq    2b
-1:  ret
-
 #ifdef DDB
 /*
  * DDB is the only routine that uses setjmp/longjmp.
@@ -423,19 +379,3 @@ ENTRY(copystr,0)
 _memtest:	.long 0 ; .globl _memtest	# Memory test in progress.
 pcbtrap:	.long 0x800001fc; .globl pcbtrap	# Safe place
 _bootdev:	.long 0; .globl _bootdev
-
-/*
- * Fill more than 64k of memory (used by bzero and memset).
- */
-ENTRY(blkfill,R2|R3|R4|R5|R6|R7)
-	movl	4(ap), r3
-	movl	8(ap), r7
-	movl	12(ap), r6
-	jbr	2f
-1:	subl2	r0, r6
-	movc5	$0,(r3),r7,r0,(r3)
-2:	movzwl	$65535,r0
-	cmpl	r6, r0
-	jgtr	1b
-	movc5	$0,(r3),r7,r6,(r3)
-	ret
diff --git a/sys/lib/libkern/arch/vax/bcmp.S b/sys/lib/libkern/arch/vax/bcmp.S
index 33ba5c2da5c..1c480988ecb 100644
--- a/sys/lib/libkern/arch/vax/bcmp.S
+++ b/sys/lib/libkern/arch/vax/bcmp.S
@@ -1 +1,56 @@
-/* No code here since kernel impliments this itself */
+/*	$OpenBSD: bcmp.S,v 1.3 2009/08/19 19:47:53 miod Exp $ */
+/*
+ * Copyright (c) 1983, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+#include <machine/asm.h>
+
+/* Since "cmpc3" is not portable across VAXen, do it the hard way */
+/*  still, this is four times faster than the generic C version on a uvax2 */
+
+ENTRY(bcmp, 0)
+	movl	12(ap),r0	# r0 = n
+	jeql	9f
+	movq	4(ap),r1	# r1 = s1, r2 = s2
+	ashl	$-2,r0,r3	# convert len to # of long words
+	jeql	2f
+1:
+	cmpl	(r1)+,(r2)+	# no "cmpq" alas, so four bytes at a time
+	jneq	9f
+	sobgtr	r3,1b
+2:
+	bicl3	$-4,r0,r3	# handle at most 3 extra bytes
+	jeql	8f
+3:
+	cmpb	(r1)+,(r2)+
+	jneq	9f
+	sobgtr	r3,3b
+8:
+	clrl	r0		# we have a match!
+9:
+	ret
diff --git a/sys/lib/libkern/arch/vax/bcopy.S b/sys/lib/libkern/arch/vax/bcopy.S
index 33ba5c2da5c..24b1d21ccb0 100644
--- a/sys/lib/libkern/arch/vax/bcopy.S
+++ b/sys/lib/libkern/arch/vax/bcopy.S
@@ -1 +1,71 @@
-/* No code here since kernel impliments this itself */
+/*	$OpenBSD: bcopy.S,v 1.3 2009/08/19 19:47:53 miod Exp $ */
+/*
+ * Copyright (c) 1983, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+/* bcopy(from, to, size) */
+
+#include <machine/asm.h>
+
+ENTRY(bcopy, R2|R3|R4|R5|R6)
+	movl	4(ap),r1
+	movl	8(ap),r3
+	movl	12(ap),r6
+	cmpl	r1,r3
+	bgtr	2f		# normal forward case
+	blss	3f		# overlapping, must do backwards
+	ret			# equal, nothing to do
+1:
+	subl2	r0,r6
+	movc3	r0,(r1),(r3)
+2:
+	movzwl	$65535,r0
+	cmpl	r6,r0
+	jgtr	1b
+	movc3	r6,(r1),(r3)
+	ret
+3:
+	addl2	r6,r1
+	addl2	r6,r3
+	movzwl	$65535,r0
+	jbr	5f
+4:
+	subl2	r0,r6
+	subl2	r0,r1
+	subl2	r0,r3
+	movc3	r0,(r1),(r3)
+	movzwl	$65535,r0
+	subl2	r0,r1
+	subl2	r0,r3
+5:
+	cmpl	r6,r0
+	jgtr	4b
+	subl2	r6,r1
+	subl2	r6,r3
+	movc3	r6,(r1),(r3)
+	ret
diff --git a/sys/lib/libkern/arch/vax/bzero.S b/sys/lib/libkern/arch/vax/bzero.S
index 33ba5c2da5c..c3fd12bb3d5 100644
--- a/sys/lib/libkern/arch/vax/bzero.S
+++ b/sys/lib/libkern/arch/vax/bzero.S
@@ -1 +1,46 @@
-/* No code here since kernel impliments this itself */
+/*	$OpenBSD: bzero.S,v 1.3 2009/08/19 19:47:53 miod Exp $ */
+/*
+ * Copyright (c) 1983, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+/* bzero(base, length) */
+
+#include <machine/asm.h>
+
+ENTRY(bzero, R2|R3|R4|R5)
+	movl	4(ap),r3
+	jbr	2f
+1:
+	subl2	r0,8(ap)
+	movc5	$0,(r3),$0,r0,(r3)
+2:
+	movzwl	$65535,r0
+	cmpl	8(ap),r0
+	jgtr	1b
+	movc5	$0,(r3),$0,8(ap),(r3)
+	ret
diff --git a/sys/lib/libkern/arch/vax/memcmp.S b/sys/lib/libkern/arch/vax/memcmp.S
new file mode 100644
index 00000000000..4ce069b3afd
--- /dev/null
+++ b/sys/lib/libkern/arch/vax/memcmp.S
@@ -0,0 +1,65 @@
+/*	$OpenBSD: memcmp.S,v 1.1 2009/08/19 19:47:53 miod Exp $ */
+/*-
+ * Copyright (c) 1990, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+/* int memcmp(s1, s2, n) */
+
+#include <machine/asm.h>
+
+ENTRY(memcmp, 0)
+	movl	12(ap),r0
+	jeql	9f
+	movq	4(ap),r1
+	ashl	$-2,r0,r3	# convert len to long words
+	jeql	2f
+1:
+	cmpl	(r1)+,(r2)+	# no "cmpq" alas
+	jneq	7f
+	sobgtr	r3,1b
+2:
+	bicl3	$-4,r0,r3	# handle at most 3 extra bytes
+	jeql	4f
+3:
+	cmpb	(r1)+,(r2)+
+	jneq	8f
+	sobgtr	r3,3b
+4:
+	clrl	r0		# we had a match
+	ret
+7:				# backup, and do a byte compare
+	tstl	-(r1)
+	tstl	-(r2)
+	movl	$4,r3
+	jbr	3b
+8:
+	movzbl	-(r1),r3
+	movzbl	-(r2),r4
+	subl3	r4,r3,r0
+9:
+	ret
diff --git a/sys/lib/libkern/arch/vax/memcpy.S b/sys/lib/libkern/arch/vax/memcpy.S
new file mode 100644
index 00000000000..46fcf60d6b2
--- /dev/null
+++ b/sys/lib/libkern/arch/vax/memcpy.S
@@ -0,0 +1,86 @@
+/*	$OpenBSD: memcpy.S,v 1.1 2009/08/19 19:47:53 miod Exp $ */
+/*-
+ * Copyright (c) 1990, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+/*
+ * void *memcpy(dst, src, size)
+ * returns dst
+ *
+ * This optimises the usual case (count < 65536) at the expense
+ * of some extra memory references and branches when count >= 65536.
+ */
+
+#include <machine/asm.h>
+
+ENTRY(memcpy, R2|R3|R4|R5)
+	movzwl	$65535,r0	/* r0 = 64K (needed below) */
+	movq	8(ap),r1	/* r1 = src, r2 = length */
+	movl	4(ap),r3	/* r3 = dst */
+	cmpl	r1,r3
+	bgtru	1f		/* normal forward case */
+	beql	2f		/* equal, nothing to do */
+	addl2	r2,r1		/* overlaps iff src<dst but src+len>dst */
+	cmpl	r1,r3
+	bgtru	4f		/* overlapping, must move backwards */
+	subl2	r2,r1
+
+1:	/* move forward */
+	cmpl	r2,r0
+	bgtru	3f		/* stupid movc3 limitation */
+	movc3	r2,(r1),(r3)	/* move it all */
+2:
+	movl	4(ap),r0	/* return original dst */
+	ret
+3:
+	subl2	r0,12(ap)	/* adjust length by 64K */
+	movc3	r0,(r1),(r3)	/* move 64K */
+	movl	12(ap),r2
+	decw	r0		/* from 0 to 65535 */
+	brb	1b		/* retry */
+
+4:	/* move backward */
+	addl2	r2,r3
+5:
+	cmpl	r2,r0
+	bgtru	6f		/* stupid movc3 limitation */
+	subl2	r2,r1
+	subl2	r2,r3
+	movc3	r2,(r1),(r3)	/* move it all */
+	movl	4(ap),r0	/* return original dst */
+	ret
+6:
+	subl2	r0,12(ap)	/* adjust length by 64K */
+	subl2	r0,r1
+	subl2	r0,r3
+	movc3	r0,(r1),(r3)	/* move 64K */
+	movl	12(ap),r2
+	decw	r0
+	subl2	r0,r1
+	subl2	r0,r3
+	brb	5b
diff --git a/sys/lib/libkern/arch/vax/memmove.S b/sys/lib/libkern/arch/vax/memmove.S
index 33ba5c2da5c..1a67e59b30e 100644
--- a/sys/lib/libkern/arch/vax/memmove.S
+++ b/sys/lib/libkern/arch/vax/memmove.S
@@ -1 +1,86 @@
-/* No code here since kernel impliments this itself */
+/*	$OpenBSD: memmove.S,v 1.3 2009/08/19 19:47:53 miod Exp $ */
+/*-
+ * Copyright (c) 1990, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+/*
+ * void *memmove(dst, src, size)
+ * returns dst
+ *
+ * This optimises the usual case (count < 65536) at the expense
+ * of some extra memory references and branches when count >= 65536.
+ */
+
+#include <machine/asm.h>
+
+ENTRY(memmove, R2|R3|R4|R5)
+	movzwl	$65535,r0	/* r0 = 64K (needed below) */
+	movq	8(ap),r1	/* r1 = src, r2 = length */
+	movl	4(ap),r3	/* r3 = dst */
+	cmpl	r1,r3
+	bgtru	1f		/* normal forward case */
+	beql	2f		/* equal, nothing to do */
+	addl2	r2,r1		/* overlaps iff src<dst but src+len>dst */
+	cmpl	r1,r3
+	bgtru	4f		/* overlapping, must move backwards */
+	subl2	r2,r1
+
+1:	/* move forward */
+	cmpl	r2,r0
+	bgtru	3f		/* stupid movc3 limitation */
+	movc3	r2,(r1),(r3)	/* move it all */
+2:
+	movl	4(ap),r0	/* return original dst */
+	ret
+3:
+	subl2	r0,12(ap)	/* adjust length by 64K */
+	movc3	r0,(r1),(r3)	/* move 64K */
+	movl	12(ap),r2
+	decw	r0		/* from 0 to 65535 */
+	brb	1b		/* retry */
+
+4:	/* move backward */
+	addl2	r2,r3
+5:
+	cmpl	r2,r0
+	bgtru	6f		/* stupid movc3 limitation */
+	subl2	r2,r1
+	subl2	r2,r3
+	movc3	r2,(r1),(r3)	/* move it all */
+	movl	4(ap),r0	/* return original dst */
+	ret
+6:
+	subl2	r0,12(ap)	/* adjust length by 64K */
+	subl2	r0,r1
+	subl2	r0,r3
+	movc3	r0,(r1),(r3)	/* move 64K */
+	movl	12(ap),r2
+	decw	r0
+	subl2	r0,r1
+	subl2	r0,r3
+	brb	5b
diff --git a/sys/lib/libkern/arch/vax/memset.S b/sys/lib/libkern/arch/vax/memset.S
new file mode 100644
index 00000000000..f8cc2331247
--- /dev/null
+++ b/sys/lib/libkern/arch/vax/memset.S
@@ -0,0 +1,48 @@
+/*	$OpenBSD: memset.S,v 1.1 2009/08/19 19:47:53 miod Exp $ */
+/*-
+ * Copyright (c) 1990, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+/* void *memset(base, c, length) */
+
+#include <machine/asm.h>
+
+ENTRY(memset, R2|R3|R4|R5)
+	movl	4(ap),r3
+1:
+	movzwl	$65535,r0
+	movq	8(ap),r1
+	cmpl	r2,r0
+	jgtru	2f
+	movc5	$0,(r3),r1,r2,(r3)
+	movl	r1,r0
+	ret
+2:
+	subl2	r0,12(ap)
+	movc5	$0,(r3),r1,r0,(r3)
+	jbr	1b
diff --git a/sys/lib/libkern/arch/vax/ovbcopy.S b/sys/lib/libkern/arch/vax/ovbcopy.S
index 33ba5c2da5c..10f0be2384c 100644
--- a/sys/lib/libkern/arch/vax/ovbcopy.S
+++ b/sys/lib/libkern/arch/vax/ovbcopy.S
@@ -1 +1 @@
-/* No code here since kernel impliments this itself */
+/* No code here since <machine/param.h> defines ovbcopy() as bcopy() */